/*
 * Copyright 2024-2025 MicroEJ Corp. All rights reserved.
 * MicroEJ Corp. PROPRIETARY/CONFIDENTIAL. Use is subject to license terms.
 */

import java.time.LocalDateTime
import java.time.format.DateTimeFormatter

plugins {
    alias(libs.plugins.android.library)
    alias(libs.plugins.kotlin.android)
    `maven-publish`
}

val baseVersion = "1.1.0"

repositories {
    google()
    mavenCentral()
}

android {
    namespace = "com.microej.wear.companion.client"
    compileSdk = 35

    defaultConfig {
        minSdk = 26
        buildToolsVersion = "35.0.0"

        consumerProguardFiles("consumer-rules.pro")
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro"
            )
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = "1.8"
    }
    packaging {
        resources.excludes.add("META-INF/*")
    }
    publishing {
        singleVariant("release") {
            withSourcesJar()
            withJavadocJar()
        }
    }
}

dependencies {
    implementation(libs.androidx.core.ktx)
    implementation(libs.kotlinx.serialization.cbor)
    implementation(libs.microej.veewear.protocol)
}

publishing {
    publications {
        register<MavenPublication>("release") {
            groupId = "com.microej.library.wear"
            artifactId = "wear-companion-client"
            version = baseVersion + if (baseVersion.endsWith("-RC")) {
                LocalDateTime.now().format(DateTimeFormatter.ofPattern("yyyyMMddHHmm"))
            } else {
                ""
            }

            afterEvaluate {
                from(components["release"])
            }
        }
    }
}

tasks.register("checkModule") {
    // I0047J-176 empty task for CI build
}